Tema: Tutorial para instalar GlovePie

buen aporte tucci cuando tenga un rato libre lo probare

Muy Muy Buen Aporte Si SeÑor

Añado al tutorial que una vez que todo esta instalado y funcionando hay que hacer correr en GlovePie unos scripts que por asi decirlo son unos programas que lo que hacen es transformar las ordenes del wiimote en lenguaje comprensible para el ordenador.

El paso a seguir es el siguiente: tras instalar Glovepie, solo tendremos que escoger el script que mas se ajuste a nuestras necesidades, copiarlo en la interfaz de GlovePie y hacer clic en Run para ejecutarlo. A continuacion os pongo unos scripts para que el wiimote haga diferentes funciones:




Para que el wiimote haga las funciones del raton

// Show wiimote forces
debug = "X="+Wiimote.RawForceX+' Y='+Wiimote.RawForceY+' Z='+Wiimote.RawForceZ

if wiimote.Up then
Mouse.WheelUp = true
wait 120 ms
Mouse.WheelUp = false
endif
if wiimote.Down then
Mouse.WheelDown = true
wait 120 ms
Mouse.WheelDown = false
endif
if wiimote.Left then
Mouse.WheelLeft = true
wait 120 ms
Mouse.WheelLeft = false
endif
if wiimote.Right then
Mouse.WheelRight = true
wait 120 ms
Mouse.WheelRight = false
endif

Mouse.RightButton = Wiimote.A
Mouse.LeftButton = Wiimote.B

Mouse.MiddleButton = Wiimote.Home
if Wiimote.Plus then
if var.osk= false then
Execute("osk")
var.osk = true
wait 300 ms
endif
endif
if Wiimote.Minus then
if var.osk = true then
ExitProgram
wait 300 ms
var.osk= false
endif
endif

if wiimote.one then
wiimote.leds = wiimote.leds + 1
if(wiimote.Leds>15)
wiimote.Leds=15
endif
wait 120 ms
endif
if wiimote.two then
wiimote.leds = wiimote.leds - 1
if(wiimote.Leds<0)>
wiimote.leds = 0
endif
wait 120 ms
endif

// set these to the offsets when the wiimote is at rest
// will be different for each wiimote most likely
var.x = Wiimote.RawForceX +12 //trim to 0
var.y = Wiimote.RawForceY -37 // trim to 0
var.z = Wiimote.RawForceZ +12 //trim to 0

//precision
var.sense0 = 500
var.thresh0x = 5
var.thresh0y = 2

var.sense = 300
var.threshx = 10
var.threshy = 5

var.sense2 = 100
var.thresh2x = 15
var.thresh2y = 8

var.sense3 = 50
var.thresh3x = 20
var.thresh3y = 12

//first sensitivity setting
//xaxis
if var.x > var.thresh0x
mouse.x = mouse.x - 1/var.sense0
endif
if var.x < -var.thresh0x
mouse.x = mouse.x + 1/var.sense0
endif

//yaxis
if var.z > var.thresh0y
mouse.y = mouse.y - 1/var.sense0
endif
if var.z < -var.thresh0y
mouse.y = mouse.y + 1/var.sense0
endif


//second sensitivity setting
//xaxis
if var.x > var.threshx
mouse.x = mouse.x - 1/var.sense
endif
if var.x < -var.threshx
mouse.x = mouse.x + 1/var.sense
endif

//yaxis
if var.z > var.threshy
mouse.y = mouse.y - 1/var.sense
endif
if var.z < -var.threshy
mouse.y = mouse.y + 1/var.sense
endif

//third sensitivity setting
//xaxis
if var.x > var.thresh2x
mouse.x = mouse.x - 1/var.sense2
endif
if var.x < -var.thresh2x
mouse.x = mouse.x + 1/var.sense2
endif

//yaxis
if var.z > var.thresh2y
mouse.y = mouse.y - 1/var.sense2
endif
if var.z < -var.thresh2y
mouse.y = mouse.y + 1/var.sense2
endif

//fourth sensitivity setting
//xaxis
if var.x > var.thresh3x
mouse.x = mouse.x - 1/var.sense3
endif
if var.x < -var.thresh3x
mouse.x = mouse.x + 1/var.sense3
endif

//yaxis
if var.z > var.thresh3y
mouse.y = mouse.y - 1/var.sense3
endif
if var.z < -var.thresh3y
mouse.y = mouse.y + 1/var.sense3
endif



Para juegos FPS

/* NOTE for this code to work right with the wiimote please
read the following */

// When configuring the offsets please put the wiimote flat and do not move it.
// These are offsets change them so that your debug output reads 0,28,0
// The debug output is at the top of this window.
// Ex if you get -7,33,-6 then change the offsets to 7,-5,6
var.xOffset = 0
var.yOffset = 0
var.zOffset = 0


// Change this if you would like your mouse to go faster
var.speed = 1

// change these to a higher number if your hands are not steady or lower if they are
var.xCutoff = 4
var.zCutoff = 4


var.xRot = Wiimote.RawForceX + var.xOffset
var.yRot = Wiimote.RawForceY + var.yOffset
var.zRot = Wiimote.RawForceZ + var.zOffset

debug = 'X:' + var.xRot + ', ' + 'Y:' + var.yRot + ', ' + 'Z:' + var.zRot

// This is the code that moves your mouse
if var.xRot > var.xCutoff then mouse.x = mouse.x - .001 * var.speed * (var.xRot - var.xCutoff)
if var.xRot < -var.xCutoff then mouse.x = mouse.x - .001 * var.speed * (var.xRot + var.xCutoff)
if var.zRot > var.zCutoff then mouse.y = mouse.y - .001 * var.speed * (var.zRot - var.zCutoff)
if var.zRot < -var.zCutoff then mouse.y = mouse.y - .001 * var.speed * (var.zRot + var.zCutoff)

/* The following is for turning wii button presses into keyboard presses and mouse clicks */
// WASD for fsp games
w = Wiimote.Up
s = Wiimote.Down
a = Wiimote.Left
d = Wiimote.Right

// Press 1 on the wiimote to press e on the keyboard
e = Wiimote.One
// Press 2 on the wiimote to press control on the keyboard
control = Wiimote.Two

// B for left click and A for right click
mouse.LeftButton = Wiimote.B
mouse.RightButton = Wiimote.A

// Plus and Minus on the wiimote to use the scroll wheel
// get for scrolling though weapens in fsp games
mouse.WheelUp = Wiimote.Plus
mouse.WheelDown = Wiimote.Minus


// Rumbles wiimote when shift is pressed on your keyboard
Wiimote.Rumble = Shift

// Have some fun and press 1, 2, 3, and/of 4 to little up the lights on the wiimote
Wiimote.Led1 = four
Wiimote.Led2 = three
Wiimote.Led3 = two
Wiimote.Led4 = one

// If you move your controler up and down quickly then it will press space
// Great for jumping on games
if var.yRot >= 100 then space = true else space = false


Para controlar juegos de la consola NES

if wiimote.Up then
Key.left = true
wait 60 ms
Key.left = false
endif
if wiimote.Down then
Key.right = true
wait 60 ms
Key.right = false
endif
if wiimote.Left then
Key.down = true
wait 60 ms
Key.down = false
endif
if wiimote.Right then
Key.up = true
wait 60 ms
Key.up = false
endif
if wiimote.one
key.Z = true
wait 60 ms
key.Z = false
ENDIF
if wiimote.Two
key.x = true
wait 60 ms
key.x = false
endif
if wiimote.Plus
key.enter = true
wait 60 ms
key.enter = false
endif
if wiimote.Minus
key.Ctrl = true
wait 60 ms
key.ctrl= false
endif


Para jugar al Need for Speed Most Wanted

//NEED FOR SPEED MOST WANTED
/* NOTE for this code to work right with the wiimote please
read the following */

// When configuring the offsets please put the wiimote flat and do not move it.
// These are offsets change them so that your debug output reads 0,28,0
// The debug output is at the top of this window.
// Ex if you get -7,33,-6 then change the offsets to 7,-5,6

var.xOffset = 4
var.yOffset = -2
var.zOffset = 6

// 1st player led on so you know it's running
Wiimote.leds = 1


// Change this if you would like your mouse to go faster
var.speed = 1

// change these to a higher number if your hands are not steady or lower if they are
var.zCutoff1 = 4
var.zCutoff2 = 8
var.zCutoff3 = 15


var.xRot = Wiimote.RawForceX + var.xOffset
var.yRot = Wiimote.RawForceY + var.yOffset
var.zRot = Wiimote.RawForceZ + var.zOffset

debug = 'X:' + var.xRot + ', ' + 'Y:' + var.yRot + ', ' + 'Z:' + var.zRot

// Car Movement
if var.zRot > var.zCutoff3 then
key.right = true
key.left = true
key.left = false
wait 20ms
key.right = false
else if var.zRot < -var.zCutoff3 then
key.left = true
key.right = true
key.right = false
wait 20ms
key.left = false
else if var.zRot > var.zCutoff2 then
key.right = true
key.left = true
key.left = false
wait 12ms
key.right = false
else if var.zRot < -var.zCutoff2 then
key.left = true
key.right = true
key.right = false
wait 12ms
key.left = false
else if var.zRot > var.zCutoff1 then
key.right = true
key.left = true
key.left = false
wait 2ms
key.right = false
else if var.zRot < -var.zCutoff1 then
key.left = true
key.right = true
key.right = false
wait 2ms
key.left = false
else
key.left = True
key.right = True
key.left = false
key.right = false
endif

l= Wiimote.Up //look behind
key.FakeRightCtrl = Wiimote.Down //speedbreaker
key.space = Wiimote.Left //HandBrake
key.alt = Wiimote.Right //nitrous

key.down = Wiimote.One // Press 1 = accel
key.up = Wiimote.Two // Press 2 = brake/reverse

key.enter = Wiimote.B //enter
t = Wiimote.A //song change

c = Wiimote.Plus //change view
r = Wiimote.Minus //reset car

key.Escape = Wiimote.Home //escape


// Useless but fun
Wiimote.Rumble = Shift


Para controlar el Windows Media Player

//Wiimote WMP Control
//Created By Xarath
//Windows Media Player must be the front window while using this! This
//is very basic and is meant for you coding-impared.
//
//Controls:
// Plus - Next Song
// Minus - Previous Song
// Home - Play/Pause
// Left - Volume down
// Right - Volume up
// Up - Speed Up
// Down - Slow down
// A - Normal Speed
// B - No use.
// 1 - Turns on rumble
// 2 - Turns off rumble


Control && F = Wiimote.Plus
Control && B = Wiimote.Minus
CTRL && P = Wiimote.Home
F9 = Wiimote.Left
F10 = Wiimote.Right
Control && Shift && N = Wiimote.A
Control && Shift && G = Wiimote.Up
Control && Shift && S = Wiimote.Down

If Wiimote.one then

Wiimote.Led1 = true
Wiimote.Led2 = true
Wiimote.Led3 = true
Wiimote.Led4 = true

wiimote.Rumble = 1
endif
//wait 50000 ms
//wiimote.Rumble = 0
If wiimote.two then

Wiimote.Led1 = false
Wiimote.Led2 = false
Wiimote.Led3 = false
Wiimote.Led4 = false

wiimote.Rumble = 0
endif

Para controlar el Google Earth

// Google Earth Interface using Wii Remote
// by J.Coulston
//
//Instructions:
// Start the GlovePIE script, then calibrate your Wiimote (see next section).
// After calibrating, make sure Google Earth is the top window.
// Tilting up, down, left and right will simulate arrow keys.
// Holding B while tilting up and down will tilt the view up and down.
// Holding B while tilting left and right will rotate the view.
// Pressing + and - will zoom when the Wiimote is level.
// Pressing Home will center the view.
// Pressing 1 will toggle fullscreen.


//Calibrate your Wiimote!
//Place the Wiimote face up on a flat surface. Change these values until the
//debug line next to the run button shows zero for each axis.
var.xOffset = 8
var.yOffset = -32
var.zOffset = 8

//Set your Wiimote LEDs to your liking. Binary value, 1-15
var.leds = 1

var.xRot = Wiimote.RawForceX + var.xOffset
var.yRot = Wiimote.RawForceY + var.yOffset
var.zRot = Wiimote.RawForceZ + var.zOffset

// Debug window output
debug = "X=" + var.xRot + " Y=" + var.yRot + " Z=" + var.zRot

Wiimote.Leds = var.leds

//Key-press and tilt functions
if abs(var.zRot) > 10 then
Shift = Wiimote.B
else
Shift = false
endif

if var.zRot >10 then
Up = true
elseif var.zRot < -10 then
Down = true
else
Up = false
Down = false
endif

if abs(var.xRot) > 15 then
Shift = Wiimote.B
else
Shift = false
endif

if var.xRot > 15 then
Left = true
elseif var.xRot < -15 then
Right = true
else
Left = false
Right = false
endif

if Wiimote.minus then
Ctrl+Down = not(abs(var.zRot)>10)
else
Ctrl = false
endif

if Wiimote.plus then
Ctrl+Up = not(abs(var.zRot)>10)
else
Ctrl = false
endif

if Wiimote.home then
r = true
else
r = false
endif

if Wiimote.One then
F11 = true
else
F11 = false
endif



Adjunto video demostrativo de como se controla el Google earth con el wiimote

Si alguien quiere que le busque algun script para alguna funcion o programa en especial que haga el favor de enviarme un privado